User-Contributed Scans

Below is a collection of advanced scans sent to us by our users over the years. StockCharts members can run these scans by copying and pasting them from this page into our Advanced Scan Workbench.

Note: For the sake of brevity, we are only adding “[type=stock]” to the beginning of each of these sample scans. In your scans, you will want to narrow down your scan universe far more than just this one clause.

Here are a few examples of commonly used clauses that you may want to add to define your scan universe:

and [country = us]   (or 'canada' or 'uk' or 'india' )
and [exchange = nyse]   (or 'nasdaq' or 'tse' or 'lse' or 'nse')
and [SMA(20,close)> 1.00]  (or a price threshold to suit you)
and [SMA(20,volume)> 100000]  (or a volume threshold to suit you)
and [group is etf]  (or 'dow30' or 'sp500')
and [optionable is true]  (limit to stocks that trade options)

Learn More. Planning Scans | Writing Scans | Scan Syntax Reference

Note: StockCharts.com makes no claims about the effectiveness of these scans for trading purposes. These scans should only be used for educational purposes, as a way for you to develop your own personal trading strategy.

---

Chip Anderson's "Strengthening Strength" Scan

Originally featured in the “ChartWatchers LIVE!” webinar series (the predecessor of StockCharts TV's MarketWatchers LIVE), this scan finds stocks with strong relative strength (i.e., high SCTR values) and increasing, positive momentum (as measured by DecisionPoint's PMO indicator).

  [type = stock]
  
  and [sctr > 90]
  and [todays sctr >= yesterdays sctr]
  and [yesterdays sctr >= 2 days ago sctr]
  and [2 days ago sctr >= 3 days ago sctr]
  and [3 days ago sctr >= 4 days ago sctr]
  
  and [todays pmo line > 0]
  and [todays pmo line > yesterdays pmo line]
  and [yesterdays pmo line > 2 days ago pmo line]
  and [2 days ago pmo line > 3 days ago pmo line]
  and [3 days ago pmo line > 4 days ago pmo line]
  
  rank by [sctr]

Anargyros Economou's "Stochastic Pop" Scan

“This scan identifies stocks ready for a possible short-term upward move. It uses Slow Stochastics to help identify pivot points at which bulls are gaining strength and closing prices continue to be at the top of the current day's trading range. I use Slow Stochastics because it does a better job of screening out noise associated from market volatility.” - Anargyros Economou

  [type = stock]
  and [today's SMA(50,volume) > 50000]
  and [today's slow stoch %k(9,3) >= today's slow stoch %d(9,3)]
  and [yesterday's slow stoch %k(9,3) < yesterday's slow stoch %d(9,3)]
  and [2 days ago slow stoch %k(9,3) < 2 days ago slow stoch %d(9,3)]
  and [3 days ago slow stoch %k(9,3) < 3 days ago slow stoch %d(9,3)]
  and [today's close > yesterday's close]

Michael Daumer's "Momentum Buy Signal" Scan

The scan looks for consensus among a stock's Moving Averages, RSI and MACD indicators. Basically, if four different signals have just become true for a given stock, that stock is returned by the scan as a potential buy candidate. The four signals are:

• The 5-day moving average is above the 15-day moving average

• The 14-day RSI is above 50

• The standard MACD line is above its signal line

• The standard MACD line is above zero

When creating the scan, the key is to remember that the four conditions must have just become true today, meaning at least one of them was false yesterday. This means we have to check for four different scenarios - one for each of the four conditions becoming true today. So our scan will have this kind of “outline” to it:

  [
    [ First condition just became true and
      other conditions also true ]
    or
    [ Second condition just became true and
      other conditions also true ]
    or
    [ Third condition just became true and
      other conditions also true ]
    or
    [ Fourth condition just became true and
      other conditions also true ]
  ]

In order for one of the conditions to just become true, we'll use the handy “crosses above” operator (“x”). For the remaining conditions inside each scenario, the “greater than” operator is used. (Think of it as the “already above” operator.) With that in mind, the first scenario would look like this:

  [SMA(5,close) x SMA(15,close)]
  and [RSI(14) > 50]
  and [MACD Line(12,26,9) > MACD Signal(12,26,9)]
  and [MACD Line(12,26,9) > 0]

Hopefully, you can see the correlation between those statements and Michael's original four signals listed above. The remainder of the scan is created by copying those four lines into each scenario of the “outline” and changing the position of the “crosses above” operator.

  [type = stock]
  and [
    [
      [SMA(5,close) x SMA(15,close)] and
      [RSI(14) > 50] and
      [MACD Line(12,26,9) > MACD Signal(12,26,9)] and
      [MACD Line(12,26,9) > 0]
    ]
    or
    [
      [SMA(5,close) > SMA(15,close)] and
      [RSI(14) x 50] and
      [MACD Line(12,26,9) > MACD Signal(12,26,9)] and
      [MACD Line(12,26,9) > 0]
    ]
    or
    [
      [SMA(5,close) > SMA(15,close)] and
      [RSI(14) > 50] and
      [MACD Line(12,26,9) x MACD Signal(12,26,9)] and
      [MACD Line(12,26,9) > 0]
    ]
    or
    [
      [SMA(5,close) > SMA(15,close)] and
      [RSI(14) > 50] and
      [MACD Line(12,26,9) > MACD Signal(12,26,9)] and
      [MACD Line(12,26,9) x 0]
    ]
  ]

Howard Pasternack's Improved "Bollinger Method IV" Scan

This scan implements Bollinger's Method IV (Confirmed Breakout) but adds additional checks for trend and volume.

In short, Method IV requires:

• Day 1. Close inside the band; bandwidth within 25% of lowest bandwidth in 6 months

• Day 2. Close outside the band

• Day 3. Close higher than Day 2

  [type = stock]
  and [SMA(20,volume) > 100000]
  and [close > yesterday's close]
  and [SMA(200,close) > 20 days ago SMA(200,close)]
  and [SMA(200,close) > 60 days ago SMA(200,close)]
  and [min(10,SMA(50,close)) > max(10,SMA(200,close))]
  and [MACD Hist(12,26,9) >= yesterday's MACD Hist(12,26,9)]
  and [2 days ago %B(20,2) < 1]
  and [2 days ago %B(20,2) > -1]
  and [yesterday's %B(20,2) > 1]
  and [min(3,BB Width(20,2)) < 1.25 * min(120,BB Width(20,2))]
  and [PVO Line(12,26,9) > yesterday's PVO Line(12,26,9)]
  and [SMA(3,volume) > 1.5 * SMA(120,volume)]
  and [Slow Stoch %K(70,3) > 50]
  and [Weekly MACD Hist(12,26,9) >= 2 weeks ago MACD Hist(12,26,9)]

Send Us Your Best Scan!

If you have a non-trivial Advanced Scan that you'd like to share with the world, please send it to [email protected], along with your full name, a detailed explanation of how the scan works and the reason you developed it. If it meets our standards for publication, we'll add it to our Advanced Scan Library!